I've blogged before about ColdFusion and trusted cache, with multiple entries on how you can clear that cache when updating files.

In ColdFusion 10, you can now clear a directory from within the CF Admin. For more fine grain control and older versions of ColdFusion, you can use my Admin extension, cacheClearer.

While these options work nicely, I needed something for my blog that skipped the administrator (which I've locked down on this server) and was quicker to use. Yes, even quicker then entering a folder in one form field.

I wrote up the following simple script that takes a base directory and gets all the files recursively. It then checks each file and sees when it was last updated. If it is within some threshold (for now, one hour), it adds it to a list that is then passed to the admin api.

<cfset files = directoryList(expandPath("../"),true,"query","*.cfc|*.cfm")>
<cfset toClear = []>
<cfset numhours = 1>
<cfloop query="files">
  <cfif dateDiff("h", datelastmodified, now()) lte numhours>
  	<cfset arrayAppend(toClear, directory & "/" & name)>
	</cfif>
</cfloop>

<cfinvoke component="cfide.adminapi.administrator" method="login" adminPassword="foo">
<cfinvoke component="cfide.adminapi.runtime" method="clearTrustedCache" templateList="#arrayToList(toClear)#">

<cfoutput>Done clearing cache. Cleared #arrayLen(toClear)# items.</cfoutput>
<cfdump var="#toClear#" label="Cleared Items">

Note - both the docs for cfdirectory and directoryList incorrectly state that only filter can be applied. As you can see in the script above that is not the case. You can pass multiple filters by delimiting them with a pipe character.

I added this to my blog admin so I can clear my cache with one button click. Hope this helps. (By the way, if one hour finds too many files, you can easily tweak the dateDiff to be minute based.)