Continuous Auto-restart With Spring Boot DevTools and Gradle

With the recent release of Spring Boot 1.3, there is a new dependency in town: Spring Boot DevTools. Which enables us to automatically restart Spring Boot applications if some classes in the class path have changed.

This is quite handy for local development, but still, you need to trigger the build phase to recompile the class. In this case, we can use Gradle's continuous build feature and automatically rebuild our project. Spring Boot DevTools will pick up the changes and restart application.

One way to do this is to add the necessary dependencies to your build.gradle. In this example, the DevTool dependency is added only when we run the bootRun task (devconfiguration). There are other features of DevTool that can be useful during development, and at other times as well. So it's up to you on how you want to organize your project.

buildscript {
    dependencies {
        classpath("org.springframework.boot:spring-boot-gradle-plugin:1.3.0.RELEASE")
    }
    repositories {
        mavenCentral()
    }
}

apply plugin: 'java'
apply plugin: 'spring-boot'

repositories {
    mavenCentral()
}

configurations {
    dev
}

dependencies {
    compile("org.springframework.boot:spring-boot-starter-web:1.3.0.RELEASE")
    compile 'org.slf4j:slf4j-api:1.7.13'

    dev("org.springframework.boot:spring-boot-devtools")
}

bootRun {
    // Use Spring Boot DevTool only when we run Gradle bootRun task
    classpath = sourceSets.main.runtimeClasspath + configurations.dev
}

After this, we just need to open two terminals:

1. At the first terminal, start Gradle build as a continuous task: gradle build --continuous
2. At the second terminal, start the Gradle bootRun task: gradle bootRun

A working example can be found here.